【VBScript】Outlookを利用して会議依頼メールを送信する

前提

・デスクトップ配下の「会議資料.txt」を添付する。必要に応じてファイルパスを変更する。
・確認のために、この記事では本当に送信(Send)はせずに、表示(Display)させる。

サンプルプログラム

Option Explicit

Dim objApp
Dim objAppt
Dim objAttendee

Set objApp = CreateObject("Outlook.Application")
Set objAppt = objApp.CreateItem(1)

'種類
'┗会議依頼メール          :1
'┗会議キャンセル通知メール:5
objAppt.MeetingStatus = 1

'参加者(必須)
Set objAttendee = objAppt.Recipients.Add("hogehoge@gmail.com")
objAttendee.Type = 1

'参加者(任意)
Set objAttendee = objAppt.Recipients.Add("piyopiyo@gmail.com")
objAttendee.Type = 2

'件名
objAppt.Subject = "XXXXの件について"

'場所
objAppt.Location = "第1会議室"

'開始時刻
objAppt.start = "2021/4/26 9:00"

'終了時刻
objAppt.End = "2021/4/26 18:00"

'終日のチェック有無
'┗あり:True
'┗無し:False
objAppt.allDayEvent = False

'返信依頼の有無
'┗あり:True
'┗無し:False
objAppt.ResponseRequested = True

'公開方法
'┗空き時間        :0
'┗仮の予定        :1
'┗予定あり        :2
'┗外出中　        :3
'┗他の場所で作業中:4
objAppt.BusyStatus = 0

'アラームあり
'┗15分:15
'┗30分:30
'┗60分:60
objAppt.ReminderSet = True
objAppt.ReminderMinutesBeforeStart = 15

'本文
objAppt.Body = "各位" & vbCrLf & vbCrLf & "お忙しい中恐れ入りますが、よろしくお願い致します。"

'添付ファイル
objAppt.Attachments.Add "C:\Users\user\Desktop\会議資料.txt"

'送信
'objAppt.Send
'表示
objAppt.Display

MsgBox ("会議依頼メール送信完了！")

'後片付け
Set objApp = Nothing
Set objAppt = Nothing
Set objAttendee = Nothing

実行結果

VBScriptからOutlookを利用して会議依頼メールを送信できた。

参考①

VBAからOutlookを使用して会議依頼メールを送信することもできます。
詳細は以下の記事をご確認ください。

参考②

C#からOutlookを使用して会議依頼メールを送信することもできます。
詳細は以下の記事をご確認ください。